10   ? CHR$(12):REM World War III - Year 2005 
11   REM              by RALPH HOSKINS
12   REM______________________________________________________ 
13   REM    special conversion for SBC 6502 - 80columnīs 
14   REM          and Win Hyperterminal - Igi 2017
15   REM______________________________________________________
20   FOR R=1 TO 7:?:NEXT R:POKE 15,80
50   ? TAB(30);"#####################"
60   ? TAB(30);"### World War III ###"
70   ? TAB(30);"#####################"
80   ? :?
100  R=1
110  ? "DESCRIPTION OF GAME (1)YES (2)NO"
120  INPUT A
125  ? 
130  IF A=2 THEN 240
140  ? "THIS IS SIMULATED ATOMIC WAR IN THE YEAR 2005,"
150  ? "BETWEEN THE USA AND THE USSR."
160  ? "YOU ARE A UNITED STATES GENERAL YOUR DESITIONS"
170  ? "MEAN VICTORY OR DEFEAT FOR THE U.S. AND LIFE OR "
180  ? "DEATH TO HUNDREDS OF THOUSANDS OF SOLDIERS"
181  ? 
185  ? "*** TYPE IN ANY NUMBER TO SEE MORE --->";
186  INPUT X
190  ? "THERE ARE 18 BATTLES"
200  ? "IF ==========   MEN LEFT   ========== = 0 FOR BOTH TEAMS"
210  ? "THE TEAM WITH THE LEAST CASAULTIES USAULY WINS THE BATTLE*"
220  ? ""
230  ? " *IF THE ORIGANAL NUMBER OF SOLDIERS DIFFERS GREATLY THIS"
235  ? " MAY NOT BE TRUE"
236  ? " *** TYPE IN ANY NUMBER TO SEE MORE --->";
237  INPUT X
238  ? 
240  ? "BATTLE #1"
250  GOTO 270
260  ? "*** TYPE IN ANY NUMBER TO SEE MORE --->";
261  INPUT X
262  ? 
265  ? "BATTLE #";R
270  ? "  USA"," USSR"
280  ? " (MEN)"," (MEN)"
290  REM .....WAS---->  X=TIME(0)
300  B=RND(0)
310  B=B*1000000
320  B=INT(B)
330  ? " "
340  REM ....WAS--->   R2=TIM(10)
350  C=RND(0): REM ....C=RND(R2)
360  C=C*1000000
370  C=INT(C)
380  ? " "
390  ? B,C
400  ? " "
410  ? ""
420  E=RND(0): REM .....E=RND(E)
430  E=E*100
440  E=INT(E)
450  ? "YOU HAVE ";E;" MISSLES "
460  F=RND(0): REM .....F=RND(F)
470  F=F*10
480  IF F<5 THEN 500
490  IF F>5 THEN 520
500  ? "YOU'RE ON THE DEFENSIVE"
510  GOTO 550
520  ? "YOU'RE ON THE OFFENSIVE"
530  ? "YOUR OFFENSIVE STRATEGIES ARE:"
540  GOTO 560
550  ? "THE DEFENSIVE STRATEGIES ARE:"
560  ? "(1)FIRE NUCLEAR MISSLES (2)FLANKING MANUEVERS"
570  ? "(3)FRONTAL ATTACK (4)SURRENDER BATTLE (5)SURRENDER WAR"
580  INPUT G
590  IF G=1 THEN 690
600  IF G=2 THEN 760
610  IF G=3 THEN 760
620  IF G=4 THEN 1560
630  IF G=5 THEN 1650
640  V=RND(0): REM ....V=TIM(1)
650  H=RND(0): REM .....H=RND(V)
660  H=H*1000000
670  H=INT(H)
680  GOTO 1090
690  ? "NUMBER OF MISSLES TO FIRE(0-";E;")"
700  INPUT I
710  IF I<10.5 THEN 1010
720  IF I>10.5 THEN IF I<40.5 THEN 1060
730  IF I>40.5 THEN IF I<E+1 THEN 640
740  ? "YOU ONLY HAVE ";E;" MISSLES"
750  GOTO 690
760  ? "NUMBER OF MEN TO CHARGE ENEMY  "
770  INPUT J
780  IF J<B+1 THEN 810
790  ? "YOU ONLY HAVE ";C;" MEN"
800  GOTO 760
810  ? "NUMBER OF MEN TO FIRE FROM STATIONARY POSITION"
820  INPUT K
830  IF J+K<B+1 THEN 860
840  ? "YOU ONLY HAVE ";B;" MEN"
850  GOTO 810
860  IF E<10 THEN 880
870  IF E>10 THEN 900
880  ? "NUMBER OF MISSLES TO FIRE(0-";E;")"
890  GOTO 910
900  ? "NUMBER OF MISSLES TO FIRE(0-10)"
910  INPUT L
920  IF L>11 THEN 970
930  M=J+K+L
940  IF M<25001 THEN 990
950  IF M>25000 THEN IF M<50001 THEN 1060
960  IF M>50000 THEN IF M<C+11 THEN 640
965  GOTO 1000
970  ? "THINK AGAIN... YOU ONLY HAVE 10 MISSLES"
980  GOTO 900
990  REM ....U=TIM(1)
1000 H=RND(0): REM .... H=RND(U)
1010 H=H*10000
1020 H=INT(H)
1030 GOTO 1090
1040 REM .... U=TIM(1)
1050 H=RND(0): REM ..... H=RND(U)
1060 H=H*100000
1061 IF H>999999 THEN 1040
1070 H=INT(H)
1080 REM .... W=TIM(1)
1090 N=RND(0): REM .... N=RND(W)
1100 N=N*10
1110 IF N<3.3 THEN 1140
1120 IF N>3.3 THEN IF N<6.6 THEN 1160
1130 IF N>6.6 THEN 1180
1140 O=1
1150 GOTO 1220
1160 O=2
1170 GOTO 1270
1180 O=3
1190 GOTO 1320
1200 ? "THE SOVIET UNION CHOSE PLAN ";O
1210 GOTO 1360
1220 P=RND(0): REM ....P=RND(P)
1230 P=P*1000000
1240 P=INT(P)
1250 GOTO 1200
1260 ? ""
1270 P=RND(0): REM ....P=RND(P)
1280 P=P*100000
1290 P=INT(P)
1300 GOTO 1200
1310 ? ""
1320 P=RND(0): REM ....P=RND(P)
1330 P=P*10000
1340 P=INT(P)
1350 GOTO 1200
1360 ? ""
1370 ? "- - - - - - - - CASUALTIES - - - - - - - - "
1380 ? "   USA","USSR"
1390 ? P,H
1400 C=C-H
1410 B=B-P
1420 IF C<.1 THEN 1440
1430 IF C>.1 THEN 1470
1440 C=0
1450 IF B>.1 THEN 1470
1460 B=0
1470 ? "==========","MEN LEFT","=========="
1480 ? "   USA","   ","   USSR"
1490 ? B,"   ",C
1500 IF B>C THEN 1520
1510 IF B<C THEN 1560
1520 ? "THE UNITED STATES WON THE BATTLE"
1530 Z=Z+1
1540 R=R+1
1550 GOTO 1590
1560 ? "THE SOVIET UNION WON THE BATTLE"
1570 Y=Y+1
1580 R=R+1
1590 IF R>18 THEN 1640
1600 GOTO 260
1610 ? "CONGRATULATIONS"
1620 ? "*****YOU WON THE WAR*****"
1630 GOTO 1670
1640 IF C>B THEN 1610
1650 ? "YOU LOST THE WAR"
1660 ? "THE USA IS NOW A COMMUNIST COUNTRY"
1670 ? "DO YOU WANT TO PLAY AGAIN (1)YES (2)NO"
1680 INPUT T
1690 IF T<1.5 THEN 100
1700 END